Model 1: Saturated Network Models

On this page, we present the Mplus model syntax used to specify saturated network models of process features, as introduced in Andresen et. al. (in prep). This syntax corresponds with models 1a and 1b, as presented in section 3.3.1 of the paper.

Please use the tabs below to navigate between syntax of model 1a (excluding random residual variance), and syntax of model 1b (including random residual variance).

Saturated Network Model 1a

The syntax for specifying Model 1a is given below.

! ---------------------------------------------------------
! GENERAL MODEL SET-UP
! ---------------------------------------------------------
TITLE:      M1a: Network of Mean and Inertia/Autoregression

DATA:
            FILE = "EXAMPLE.dat";

VARIABLE:
  
            NAMES = ID hour Y1 Y2 Y3;
            MISSING=.;

            CLUSTER = ID;
            
            USEVAR = Y1 Y2 Y3 ;
            LAGGED = Y1(1) Y2(1) Y3(1);
            
            TINTERVAL = hour(1);
            MISSING = ALL(999);
            
ANALYSIS:

            TYPE = TWOLEVEL RANDOM;
            ESTIMATOR = BAYES;
            BITERATIONS = (10000);
            CHAINS=2;
            PROCESSORS = 30;


! ---------------------------------------------------------
! MODEL DEFINITION
! ---------------------------------------------------------
MODEL:
  
%WITHIN%

! ---------------------------------------------------------
! WITHIN-PERSON (micro-level) model
! Y1–Y3 = burst-specific means (M1–M3 in the paper)
! ---------------------------------------------------------

! PER BURST: AR(1) PROCESS WITH RANDOM AUTOREGRESSION
! A1–A3 correspond to autoregressive effects in the manuscript
! Note that here we can choose the name of the AR effect freely 

            A1 | Y1 ON Y1&1;   ! A1
            A2 | Y2 ON Y2&1;   ! A2
            A3 | Y3 ON Y3&1;   ! A3

! SET WITHIN-BURST COVARIANCES TO ZERO
            Y1-Y3 WITH Y1-Y3@0;


%BETWEEN%

! ---------------------------------------------------------
! NOTE ON NOTATION:
! Y1–Y3 = burst-specific means (M1–M3)
! A1–A3 = autoregressive effects (A1–A3)
! ---------------------------------------------------------

! Unconstrained covariance matrix of process features (M and A)
! This returns this saturated network model

            Y1-Y3 A1-A3 WITH
            Y1-Y3 A1-A3;

Saturated Network Model 1b

The syntax for specifying Model 1b is given below.

! ---------------------------------------------------------
! GENERAL MODEL SET-UP
! ---------------------------------------------------------

TITLE:      M1b: Network of Mean and Inertia/Autoregression and Random Residual Variance

DATA:
            FILE = "EXAMPLE.dat";

VARIABLE:
  
            NAMES = ID hour Y1 Y2 Y3;
            MISSING=.;

            CLUSTER = ID;
            
            USEVAR = Y1 Y2 Y3 ;
            LAGGED = Y1(1) Y2(1) Y3(1);
            
            TINTERVAL = hour(1);
            MISSING = ALL(999);
            
ANALYSIS:

            TYPE = TWOLEVEL RANDOM;
            ESTIMATOR = BAYES;
            BITERATIONS = (10000);
            CHAINS=2;
            PROCESSORS = 30;

! ---------------------------------------------------------
! MODEL DEFINITION
! ---------------------------------------------------------

MODEL:
  
%WITHIN%

! ---------------------------------------------------------
! WITHIN-PERSON (micro-level) model
! ---------------------------------------------------------

! RANDOM AUTOREGRESSION (A)

            A1 | Y1 ON Y1&1;   ! A1
            A2 | Y2 ON Y2&1;   ! A2
            A3 | Y3 ON Y3&1;   ! A3


! RANDOM RESIDUAL VARIANCE/ COMPOUND (C)

            C1 | Y1;           ! C1
            C2 | Y2;           ! C2
            C3 | Y3;           ! C3


%BETWEEN%

! ---------------------------------------------------------
! NOTE ON NOTATION:
! Y1–Y3 = burst-specific means (M1–M3)
! A1–A3 = autoregressive effects
! C1–C3 = compound / innovation variances
! ---------------------------------------------------------

! Unconstrained covariance matrix of process features (M, A, C)

            Y1-Y3 A1-A3 C1-C3 WITH
            Y1-Y3 A1-A3 C1-C3;